~ start

do Patient.marker.fill(0)
set Patient.dialog_tree = Patient.build_dialog_tree([21,22,23,24,31,32,33,41,42,43,51,52,53,61,62,63])

do Globals.release_display.emit("[color=orange_red]ERROR[/color]")
do Globals.terminate_display.emit("[color=orange_red]ERROR[/color]")
set Globals.buttons_activated = false

[#peaceful] A pale man stands before you, seemingly naked, eyes and mouth shut, looking somehow muscular and famished at the same time.


~ part_1

- Who are you ?
	=> part_2

- What do you want ?
	=> part_2

- What did you do ? Why's my computer malfunctioning ?
	=> part_2

- Why are you naked ?
	=> part_2

- Listen up you starving old fart, you better stop whatever bullshit you're doing, or you're in for a reaaally bad time.
	=> part_2


~ part_2
do Patient.marker[1] = 2
????: [#peaceful] ...
[#neutral] As he opens his eye and mouths, a ragged, raspy voice pours out of both his mouths, every vowel trickling down squirming bloodshot tongues.
~ part_2_0
????: [#neutral] [color=orange]... iS... tHe SkY... bLuE ?[/color]

- What the fuck is this oh my god [if Patient.dialog_tree[21] == "not_asked"]
	set Patient.dialog_tree[21] = "asked"
	=> part_angry
	
- How do you even eat ? Do you throw food in both your mouths at the same time ? [if Patient.dialog_tree[22] == "not_asked"]
	set Patient.dialog_tree[22] = "asked"
	=> part_angry

- That would depend on the definition of "blue". [if Patient.dialog_tree[23] == "not_asked"]
	set Patient.dialog_tree[23] = "asked"
	=> part_angry

- No, the sky is not blue. [if Patient.dialog_tree[24] == "not_asked"]
	set Patient.dialog_tree[24] = "asked"
	=> part_angry

- Yes, the sky is blue indeed.
	=> part_3


~ part_3
do Patient.marker[1] = 3
[#smiling] Through the contraction of countless unnatural muscles, you seem to discern a gleam of... contentment.
~ part_3_0
????: [#neutral] [color=gold]... dO YoU... lIke ME ?[/color]

- Yes, I do. Why wouldn't I like you ? [if Patient.dialog_tree[31] == "not_asked"]
	set Patient.dialog_tree[31] = "asked"
	=> part_angry
- No, you look horrifying.
	=> part_4
- No, we barely know each other.
	=> part_4
- You remind me of when I wake up, but infinitely worse. [if Patient.dialog_tree[32] == "not_asked"]
	set Patient.dialog_tree[32] = "asked"
	=> part_angry
- You are beautiful. Never let anyone tell you otherwise. [if Patient.dialog_tree[33] == "not_asked"]
	set Patient.dialog_tree[33] = "asked"
	=> part_angry

~ part_4
do Patient.marker[1] = 4
[#smiling] The same unnatural twitching of flesh covers its face. It seems pleased.
~ part_4_0
????: [#neutral] [color=yellow]... aRe yOu... WhaT yOu EAT ?[/color]

- If you're talking about the proverbial saying, yeah I guess... ? Maybe ? [if Patient.dialog_tree[41] == "not_asked"]
	set Patient.dialog_tree[41] = "asked"
	=> part_angry
- Is that a threat, old freak ? [if Patient.dialog_tree[42] == "not_asked"]
	set Patient.dialog_tree[42] = "asked"
	=> part_angry
- Yes.
	=> part_5
- No, that's a stupid saying.
	=> part_5
- Enough with the stupid questions. What do you want ? [if Patient.dialog_tree[43] == "not_asked"]
	set Patient.dialog_tree[43] = "asked"
	=> part_angry


~ part_5
do Patient.marker[1] = 5
[#happy] The creature's facial features stretch even further, communicating marked enjoyment.
~ part_5_0
????: [#neutral] [color=yellow_green]... dO yOu wIsH tO HaVe a CHILD ?[/color]

- Already have, and I don't wish for more. [if Patient.dialog_tree[51] == "not_asked"]
	set Patient.dialog_tree[51] = "asked"
	=> part_angry
- Not in this economy, no.
	=> part_6
- Yes, of course.
	=> part_6
- Maybe one day, when I'm ready. [if Patient.dialog_tree[52] == "not_asked"]
	set Patient.dialog_tree[52] = "asked"
	=> part_angry
- What are you, my life coach ? [if Patient.dialog_tree[53] == "not_asked"]
	set Patient.dialog_tree[53] = "asked"
	=> part_angry

~ part_6
do Patient.marker[1] = 6
[#happy] You can hear a faint giggling echoing back and forth between the two mouths. The creature is delighted.
~ part_6_0
????: [#smiling] [color=forest_green]... iF i ATE yOuR chIlD... wOuLd YoU lIke ME ??[/color]

- Are you serious ? [if Patient.dialog_tree[61] == "not_asked"]
	set Patient.dialog_tree[61] = "asked"
	=> part_angry
- No, and I would absolutely hate you and try to kill you.
	=> part_7
- Yes, please consume my offspring, great old one.
	=> part_7
- So that's where you were going with these weird questions. [if Patient.dialog_tree[62] == "not_asked"]
	set Patient.dialog_tree[62] = "asked"
	=> part_angry
- If you get anywhere near my kids I'm blowing your brains off on the spot. [if Patient.dialog_tree[63] == "not_asked"]
	set Patient.dialog_tree[63] = "asked"
	=> part_angry

~ part_7
[#elated] The creature erupts in laughter, elation permeating every fiber of its alien muscles.
????: [#elated] [color=lime_green] ... I ... cOmPReHEnD.[/color]
=> part_good_end

~ part_angry
if Patient.marker[2] >= 2
	=> part_bad_end
else
	do Patient.marker[2] += 1

if Patient.marker[2] == 1
	[#irritated] The creature's mouths distort with annoyance. Provoking it again seems unwise.
	????: [#angry] [color=orange_red]... aNsWeR... ME.[/color]
elif Patient.marker[2] == 2
	[#angry] The creature's eye reddens with exasperation. Angering it once more is akin to certain death.
	????: [#angry] [color=red]... eNoUgH... pRaTTlE.[/color]
	
if Patient.marker[1] == 2
	=> part_2_0
elif Patient.marker[1] == 3
	=> part_3_0
elif Patient.marker[1] == 4
	=> part_4_0
elif Patient.marker[1] == 5
	=> part_5_0
elif Patient.marker[1] == 6
	=> part_6_0


~ part_bad_end
[#furious] The creature howls with rage at your answers. As its features contort into a grotesque parody of human fury, you feel your mind melt into nothingness.
do UI.game_over.reveal()
=> END


~ part_good_end
[#peaceful] The creature falls silent once more, swallowing its eye back down its throat. It is appeased.
do Globals.release_display.emit("[color=dark_green]RELEASE[/color]")
do Globals.terminate_display.emit("[color=dark_red]TERMINATE[/color]")
set Globals.buttons_activated = true

do Globals.console_message.emit("[color=dark_orange]ALLOTED ASSESSMENT TIME ELAPSED[/color]\n\n[color=orange_red]PLEASE MAKE A DECISION[/color]")
=> END


~ terminate
[#peaceful] The creature remains still as the doors close.
do Globals.color_change.emit("red")
do Globals.clear_patient.emit("terminate")
=> END


~ release
[#peaceful] The creature remains still as the doors close.
do Globals.color_change.emit("green")
do Globals.clear_patient.emit("release")
=> END